<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#! perl

# Getopt::Long.pm -- Universal options parsing
# Author          : Johan Vromans
# Created On      : Tue Sep 11 15:00:12 1990
# Last Modified By: Johan Vromans
# Last Modified On: Sat May 27 12:11:39 2017
# Update Count    : 1715
# Status          : Released

################ Module Preamble ################

use 5.004;

use strict;
use warnings;

package Getopt::Long;

use vars qw($VERSION);
$VERSION        =  2.50;
# For testing versions only.
use vars qw($VERSION_STRING);
$VERSION_STRING = "2.50";

use Exporter;
use vars qw(@ISA @EXPORT @EXPORT_OK);
@ISA = qw(Exporter);

# Exported subroutines.
sub GetOptions(@);		# always
sub GetOptionsFromArray(@);	# on demand
sub GetOptionsFromString(@);	# on demand
sub Configure(@);		# on demand
sub HelpMessage(@);		# on demand
sub VersionMessage(@);		# in demand

BEGIN {
    # Init immediately so their contents can be used in the 'use vars' below.
    @EXPORT    = qw(&amp;GetOptions $REQUIRE_ORDER $PERMUTE $RETURN_IN_ORDER);
    @EXPORT_OK = qw(&amp;HelpMessage &amp;VersionMessage &amp;Configure
		    &amp;GetOptionsFromArray &amp;GetOptionsFromString);
}

# User visible variables.
use vars @EXPORT, @EXPORT_OK;
use vars qw($error $debug $major_version $minor_version);
# Deprecated visible variables.
use vars qw($autoabbrev $getopt_compat $ignorecase $bundling $order
	    $passthrough);
# Official invisible variables.
use vars qw($genprefix $caller $gnu_compat $auto_help $auto_version $longprefix);

# Really invisible variables.
my $bundling_values;

# Public subroutines.
sub config(@);			# deprecated name

# Private subroutines.
sub ConfigDefaults();
sub ParseOptionSpec($$);
sub OptCtl($);
sub FindOption($$$$$);
sub ValidValue ($$$$$);

################ Local Variables ################

# $requested_version holds the version that was mentioned in the 'use'
# or 'require', if any. It can be used to enable or disable specific
# features.
my $requested_version = 0;

################ Resident subroutines ################

sub ConfigDefaults() {
    # Handle POSIX compliancy.
    if ( defined $ENV{"POSIXLY_CORRECT"} ) {
	$genprefix = "(--|-)";
	$autoabbrev = 0;		# no automatic abbrev of options
	$bundling = 0;			# no bundling of single letter switches
	$getopt_compat = 0;		# disallow '+' to start options
	$order = $REQUIRE_ORDER;
    }
    else {
	$genprefix = "(--|-|\\+)";
	$autoabbrev = 1;		# automatic abbrev of options
	$bundling = 0;			# bundling off by default
	$getopt_compat = 1;		# allow '+' to start options
	$order = $PERMUTE;
    }
    # Other configurable settings.
    $debug = 0;			# for debugging
    $error = 0;			# error tally
    $ignorecase = 1;		# ignore case when matching options
    $passthrough = 0;		# leave unrecognized options alone
    $gnu_compat = 0;		# require --opt=val if value is optional
    $longprefix = "(--)";       # what does a long prefix look like
    $bundling_values = 0;	# no bundling of values
}

# Override import.
sub import {
    my $pkg = shift;		# package
    my @syms = ();		# symbols to import
    my @config = ();		# configuration
    my $dest = \@syms;		# symbols first
    for ( @_ ) {
	if ( $_ eq ':config' ) {
	    $dest = \@config;	# config next
	    next;
	}
	push(@$dest, $_);	# push
    }
    # Hide one level and call super.
    local $Exporter::ExportLevel = 1;
    push(@syms, qw(&amp;GetOptions)) if @syms; # always export GetOptions
    $requested_version = 0;
    $pkg-&gt;SUPER::import(@syms);
    # And configure.
    Configure(@config) if @config;
}

################ Initialization ################

# Values for $order. See GNU getopt.c for details.
($REQUIRE_ORDER, $PERMUTE, $RETURN_IN_ORDER) = (0..2);
# Version major/minor numbers.
($major_version, $minor_version) = $VERSION =~ /^(\d+)\.(\d+)/;

ConfigDefaults();

################ OO Interface ################

package Getopt::Long::Parser;

# Store a copy of the default configuration. Since ConfigDefaults has
# just been called, what we get from Configure is the default.
my $default_config = do {
    Getopt::Long::Configure ()
};

sub new {
    my $that = shift;
    my $class = ref($that) || $that;
    my %atts = @_;

    # Register the callers package.
    my $self = { caller_pkg =&gt; (caller)[0] };

    bless ($self, $class);

    # Process config attributes.
    if ( defined $atts{config} ) {
	my $save = Getopt::Long::Configure ($default_config, @{$atts{config}});
	$self-&gt;{settings} = Getopt::Long::Configure ($save);
	delete ($atts{config});
    }
    # Else use default config.
    else {
	$self-&gt;{settings} = $default_config;
    }

    if ( %atts ) {		# Oops
	die(__PACKAGE__.": unhandled attributes: ".
	    join(" ", sort(keys(%atts)))."\n");
    }

    $self;
}

sub configure {
    my ($self) = shift;

    # Restore settings, merge new settings in.
    my $save = Getopt::Long::Configure ($self-&gt;{settings}, @_);

    # Restore orig config and save the new config.
    $self-&gt;{settings} = Getopt::Long::Configure ($save);
}

sub getoptions {
    my ($self) = shift;

    return $self-&gt;getoptionsfromarray(\@ARGV, @_);
}

sub getoptionsfromarray {
    my ($self) = shift;

    # Restore config settings.
    my $save = Getopt::Long::Configure ($self-&gt;{settings});

    # Call main routine.
    my $ret = 0;
    $Getopt::Long::caller = $self-&gt;{caller_pkg};

    eval {
	# Locally set exception handler to default, otherwise it will
	# be called implicitly here, and again explicitly when we try
	# to deliver the messages.
	local ($SIG{__DIE__}) = 'DEFAULT';
	$ret = Getopt::Long::GetOptionsFromArray (@_);
    };

    # Restore saved settings.
    Getopt::Long::Configure ($save);

    # Handle errors and return value.
    die ($@) if $@;
    return $ret;
}

package Getopt::Long;

################ Back to Normal ################

# Indices in option control info.
# Note that ParseOptions uses the fields directly. Search for 'hard-wired'.
use constant CTL_TYPE    =&gt; 0;
#use constant   CTL_TYPE_FLAG   =&gt; '';
#use constant   CTL_TYPE_NEG    =&gt; '!';
#use constant   CTL_TYPE_INCR   =&gt; '+';
#use constant   CTL_TYPE_INT    =&gt; 'i';
#use constant   CTL_TYPE_INTINC =&gt; 'I';
#use constant   CTL_TYPE_XINT   =&gt; 'o';
#use constant   CTL_TYPE_FLOAT  =&gt; 'f';
#use constant   CTL_TYPE_STRING =&gt; 's';

use constant CTL_CNAME   =&gt; 1;

use constant CTL_DEFAULT =&gt; 2;

use constant CTL_DEST    =&gt; 3;
 use constant   CTL_DEST_SCALAR =&gt; 0;
 use constant   CTL_DEST_ARRAY  =&gt; 1;
 use constant   CTL_DEST_HASH   =&gt; 2;
 use constant   CTL_DEST_CODE   =&gt; 3;

use constant CTL_AMIN    =&gt; 4;
use constant CTL_AMAX    =&gt; 5;

# FFU.
#use constant CTL_RANGE   =&gt; ;
#use constant CTL_REPEAT  =&gt; ;

# Rather liberal patterns to match numbers.
use constant PAT_INT   =&gt; "[-+]?_*[0-9][0-9_]*";
use constant PAT_XINT  =&gt;
  "(?:".
	  "[-+]?_*[1-9][0-9_]*".
  "|".
	  "0x_*[0-9a-f][0-9a-f_]*".
  "|".
	  "0b_*[01][01_]*".
  "|".
	  "0[0-7_]*".
  ")";
use constant PAT_FLOAT =&gt;
  "[-+]?".			# optional sign
  "(?=[0-9.])".			# must start with digit or dec.point
  "[0-9_]*".			# digits before the dec.point
  "(\.[0-9_]+)?".		# optional fraction
  "([eE][-+]?[0-9_]+)?";	# optional exponent

sub GetOptions(@) {
    # Shift in default array.
    unshift(@_, \@ARGV);
    # Try to keep caller() and Carp consistent.
    goto &amp;GetOptionsFromArray;
}

sub GetOptionsFromString(@) {
    my ($string) = shift;
    require Text::ParseWords;
    my $args = [ Text::ParseWords::shellwords($string) ];
    $caller ||= (caller)[0];	# current context
    my $ret = GetOptionsFromArray($args, @_);
    return ( $ret, $args ) if wantarray;
    if ( @$args ) {
	$ret = 0;
	warn("GetOptionsFromString: Excess data \"@$args\" in string \"$string\"\n");
    }
    $ret;
}

sub GetOptionsFromArray(@) {

    my ($argv, @optionlist) = @_;	# local copy of the option descriptions
    my $argend = '--';		# option list terminator
    my %opctl = ();		# table of option specs
    my $pkg = $caller || (caller)[0];	# current context
				# Needed if linkage is omitted.
    my @ret = ();		# accum for non-options
    my %linkage;		# linkage
    my $userlinkage;		# user supplied HASH
    my $opt;			# current option
    my $prefix = $genprefix;	# current prefix

    $error = '';

    if ( $debug ) {
	# Avoid some warnings if debugging.
	local ($^W) = 0;
	print STDERR
	  ("Getopt::Long $Getopt::Long::VERSION ",
	   "called from package \"$pkg\".",
	   "\n  ",
	   "argv: ",
	   defined($argv)
	   ? UNIVERSAL::isa( $argv, 'ARRAY' ) ? "(@$argv)" : $argv
	   : "&lt;undef&gt;",
	   "\n  ",
	   "autoabbrev=$autoabbrev,".
	   "bundling=$bundling,",
	   "bundling_values=$bundling_values,",
	   "getopt_compat=$getopt_compat,",
	   "gnu_compat=$gnu_compat,",
	   "order=$order,",
	   "\n  ",
	   "ignorecase=$ignorecase,",
	   "requested_version=$requested_version,",
	   "passthrough=$passthrough,",
	   "genprefix=\"$genprefix\",",
	   "longprefix=\"$longprefix\".",
	   "\n");
    }

    # Check for ref HASH as first argument.
    # First argument may be an object. It's OK to use this as long
    # as it is really a hash underneath.
    $userlinkage = undef;
    if ( @optionlist &amp;&amp; ref($optionlist[0]) and
	 UNIVERSAL::isa($optionlist[0],'HASH') ) {
	$userlinkage = shift (@optionlist);
	print STDERR ("=&gt; user linkage: $userlinkage\n") if $debug;
    }

    # See if the first element of the optionlist contains option
    # starter characters.
    # Be careful not to interpret '&lt;&gt;' as option starters.
    if ( @optionlist &amp;&amp; $optionlist[0] =~ /^\W+$/
	 &amp;&amp; !($optionlist[0] eq '&lt;&gt;'
	      &amp;&amp; @optionlist &gt; 0
	      &amp;&amp; ref($optionlist[1])) ) {
	$prefix = shift (@optionlist);
	# Turn into regexp. Needs to be parenthesized!
	$prefix =~ s/(\W)/\\$1/g;
	$prefix = "([" . $prefix . "])";
	print STDERR ("=&gt; prefix=\"$prefix\"\n") if $debug;
    }

    # Verify correctness of optionlist.
    %opctl = ();
    while ( @optionlist ) {
	my $opt = shift (@optionlist);

	unless ( defined($opt) ) {
	    $error .= "Undefined argument in option spec\n";
	    next;
	}

	# Strip leading prefix so people can specify "--foo=i" if they like.
	$opt = $+ if $opt =~ /^$prefix+(.*)$/s;

	if ( $opt eq '&lt;&gt;' ) {
	    if ( (defined $userlinkage)
		&amp;&amp; !(@optionlist &gt; 0 &amp;&amp; ref($optionlist[0]))
		&amp;&amp; (exists $userlinkage-&gt;{$opt})
		&amp;&amp; ref($userlinkage-&gt;{$opt}) ) {
		unshift (@optionlist, $userlinkage-&gt;{$opt});
	    }
	    unless ( @optionlist &gt; 0
		    &amp;&amp; ref($optionlist[0]) &amp;&amp; ref($optionlist[0]) eq 'CODE' ) {
		$error .= "Option spec &lt;&gt; requires a reference to a subroutine\n";
		# Kill the linkage (to avoid another error).
		shift (@optionlist)
		  if @optionlist &amp;&amp; ref($optionlist[0]);
		next;
	    }
	    $linkage{'&lt;&gt;'} = shift (@optionlist);
	    next;
	}

	# Parse option spec.
	my ($name, $orig) = ParseOptionSpec ($opt, \%opctl);
	unless ( defined $name ) {
	    # Failed. $orig contains the error message. Sorry for the abuse.
	    $error .= $orig;
	    # Kill the linkage (to avoid another error).
	    shift (@optionlist)
	      if @optionlist &amp;&amp; ref($optionlist[0]);
	    next;
	}

	# If no linkage is supplied in the @optionlist, copy it from
	# the userlinkage if available.
	if ( defined $userlinkage ) {
	    unless ( @optionlist &gt; 0 &amp;&amp; ref($optionlist[0]) ) {
		if ( exists $userlinkage-&gt;{$orig} &amp;&amp;
		     ref($userlinkage-&gt;{$orig}) ) {
		    print STDERR ("=&gt; found userlinkage for \"$orig\": ",
				  "$userlinkage-&gt;{$orig}\n")
			if $debug;
		    unshift (@optionlist, $userlinkage-&gt;{$orig});
		}
		else {
		    # Do nothing. Being undefined will be handled later.
		    next;
		}
	    }
	}

	# Copy the linkage. If omitted, link to global variable.
	if ( @optionlist &gt; 0 &amp;&amp; ref($optionlist[0]) ) {
	    print STDERR ("=&gt; link \"$orig\" to $optionlist[0]\n")
		if $debug;
	    my $rl = ref($linkage{$orig} = shift (@optionlist));

	    if ( $rl eq "ARRAY" ) {
		$opctl{$name}[CTL_DEST] = CTL_DEST_ARRAY;
	    }
	    elsif ( $rl eq "HASH" ) {
		$opctl{$name}[CTL_DEST] = CTL_DEST_HASH;
	    }
	    elsif ( $rl eq "SCALAR" || $rl eq "REF" ) {
#		if ( $opctl{$name}[CTL_DEST] == CTL_DEST_ARRAY ) {
#		    my $t = $linkage{$orig};
#		    $$t = $linkage{$orig} = [];
#		}
#		elsif ( $opctl{$name}[CTL_DEST] == CTL_DEST_HASH ) {
#		}
#		else {
		    # Ok.
#		}
	    }
	    elsif ( $rl eq "CODE" ) {
		# Ok.
	    }
	    else {
		$error .= "Invalid option linkage for \"$opt\"\n";
	    }
	}
	else {
	    # Link to global $opt_XXX variable.
	    # Make sure a valid perl identifier results.
	    my $ov = $orig;
	    $ov =~ s/\W/_/g;
	    if ( $opctl{$name}[CTL_DEST] == CTL_DEST_ARRAY ) {
		print STDERR ("=&gt; link \"$orig\" to \@$pkg","::opt_$ov\n")
		    if $debug;
		eval ("\$linkage{\$orig} = \\\@".$pkg."::opt_$ov;");
	    }
	    elsif ( $opctl{$name}[CTL_DEST] == CTL_DEST_HASH ) {
		print STDERR ("=&gt; link \"$orig\" to \%$pkg","::opt_$ov\n")
		    if $debug;
		eval ("\$linkage{\$orig} = \\\%".$pkg."::opt_$ov;");
	    }
	    else {
		print STDERR ("=&gt; link \"$orig\" to \$$pkg","::opt_$ov\n")
		    if $debug;
		eval ("\$linkage{\$orig} = \\\$".$pkg."::opt_$ov;");
	    }
	}

	if ( $opctl{$name}[CTL_TYPE] eq 'I'
	     &amp;&amp; ( $opctl{$name}[CTL_DEST] == CTL_DEST_ARRAY
		  || $opctl{$name}[CTL_DEST] == CTL_DEST_HASH )
	   ) {
	    $error .= "Invalid option linkage for \"$opt\"\n";
	}

    }

    $error .= "GetOptionsFromArray: 1st parameter is not an array reference\n"
      unless $argv &amp;&amp; UNIVERSAL::isa( $argv, 'ARRAY' );

    # Bail out if errors found.
    die ($error) if $error;
    $error = 0;

    # Supply --version and --help support, if needed and allowed.
    if ( defined($auto_version) ? $auto_version : ($requested_version &gt;= 2.3203) ) {
	if ( !defined($opctl{version}) ) {
	    $opctl{version} = ['','version',0,CTL_DEST_CODE,undef];
	    $linkage{version} = \&amp;VersionMessage;
	}
	$auto_version = 1;
    }
    if ( defined($auto_help) ? $auto_help : ($requested_version &gt;= 2.3203) ) {
	if ( !defined($opctl{help}) &amp;&amp; !defined($opctl{'?'}) ) {
	    $opctl{help} = $opctl{'?'} = ['','help',0,CTL_DEST_CODE,undef];
	    $linkage{help} = \&amp;HelpMessage;
	}
	$auto_help = 1;
    }

    # Show the options tables if debugging.
    if ( $debug ) {
	my ($arrow, $k, $v);
	$arrow = "=&gt; ";
	while ( ($k,$v) = each(%opctl) ) {
	    print STDERR ($arrow, "\$opctl{$k} = $v ", OptCtl($v), "\n");
	    $arrow = "   ";
	}
    }

    # Process argument list
    my $goon = 1;
    while ( $goon &amp;&amp; @$argv &gt; 0 ) {

	# Get next argument.
	$opt = shift (@$argv);
	print STDERR ("=&gt; arg \"", $opt, "\"\n") if $debug;

	# Double dash is option list terminator.
	if ( defined($opt) &amp;&amp; $opt eq $argend ) {
	  push (@ret, $argend) if $passthrough;
	  last;
	}

	# Look it up.
	my $tryopt = $opt;
	my $found;		# success status
	my $key;		# key (if hash type)
	my $arg;		# option argument
	my $ctl;		# the opctl entry

	($found, $opt, $ctl, $arg, $key) =
	  FindOption ($argv, $prefix, $argend, $opt, \%opctl);

	if ( $found ) {

	    # FindOption undefines $opt in case of errors.
	    next unless defined $opt;

	    my $argcnt = 0;
	    while ( defined $arg ) {

		# Get the canonical name.
		print STDERR ("=&gt; cname for \"$opt\" is ") if $debug;
		$opt = $ctl-&gt;[CTL_CNAME];
		print STDERR ("\"$ctl-&gt;[CTL_CNAME]\"\n") if $debug;

		if ( defined $linkage{$opt} ) {
		    print STDERR ("=&gt; ref(\$L{$opt}) -&gt; ",
				  ref($linkage{$opt}), "\n") if $debug;

		    if ( ref($linkage{$opt}) eq 'SCALAR'
			 || ref($linkage{$opt}) eq 'REF' ) {
			if ( $ctl-&gt;[CTL_TYPE] eq '+' ) {
			    print STDERR ("=&gt; \$\$L{$opt} += \"$arg\"\n")
			      if $debug;
			    if ( defined ${$linkage{$opt}} ) {
			        ${$linkage{$opt}} += $arg;
			    }
		            else {
			        ${$linkage{$opt}} = $arg;
			    }
			}
			elsif ( $ctl-&gt;[CTL_DEST] == CTL_DEST_ARRAY ) {
			    print STDERR ("=&gt; ref(\$L{$opt}) auto-vivified",
					  " to ARRAY\n")
			      if $debug;
			    my $t = $linkage{$opt};
			    $$t = $linkage{$opt} = [];
			    print STDERR ("=&gt; push(\@{\$L{$opt}, \"$arg\")\n")
			      if $debug;
			    push (@{$linkage{$opt}}, $arg);
			}
			elsif ( $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ) {
			    print STDERR ("=&gt; ref(\$L{$opt}) auto-vivified",
					  " to HASH\n")
			      if $debug;
			    my $t = $linkage{$opt};
			    $$t = $linkage{$opt} = {};
			    print STDERR ("=&gt; \$\$L{$opt}-&gt;{$key} = \"$arg\"\n")
			      if $debug;
			    $linkage{$opt}-&gt;{$key} = $arg;
			}
			else {
			    print STDERR ("=&gt; \$\$L{$opt} = \"$arg\"\n")
			      if $debug;
			    ${$linkage{$opt}} = $arg;
		        }
		    }
		    elsif ( ref($linkage{$opt}) eq 'ARRAY' ) {
			print STDERR ("=&gt; push(\@{\$L{$opt}, \"$arg\")\n")
			    if $debug;
			push (@{$linkage{$opt}}, $arg);
		    }
		    elsif ( ref($linkage{$opt}) eq 'HASH' ) {
			print STDERR ("=&gt; \$\$L{$opt}-&gt;{$key} = \"$arg\"\n")
			    if $debug;
			$linkage{$opt}-&gt;{$key} = $arg;
		    }
		    elsif ( ref($linkage{$opt}) eq 'CODE' ) {
			print STDERR ("=&gt; &amp;L{$opt}(\"$opt\"",
				      $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ? ", \"$key\"" : "",
				      ", \"$arg\")\n")
			    if $debug;
			my $eval_error = do {
			    local $@;
			    local $SIG{__DIE__}  = 'DEFAULT';
			    eval {
				&amp;{$linkage{$opt}}
				  (Getopt::Long::CallBack-&gt;new
				   (name    =&gt; $opt,
				    ctl     =&gt; $ctl,
				    opctl   =&gt; \%opctl,
				    linkage =&gt; \%linkage,
				    prefix  =&gt; $prefix,
				   ),
				   $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ? ($key) : (),
				   $arg);
			    };
			    $@;
			};
			print STDERR ("=&gt; die($eval_error)\n")
			  if $debug &amp;&amp; $eval_error ne '';
			if ( $eval_error =~ /^!/ ) {
			    if ( $eval_error =~ /^!FINISH\b/ ) {
				$goon = 0;
			    }
			}
			elsif ( $eval_error ne '' ) {
			    warn ($eval_error);
			    $error++;
			}
		    }
		    else {
			print STDERR ("Invalid REF type \"", ref($linkage{$opt}),
				      "\" in linkage\n");
			die("Getopt::Long -- internal error!\n");
		    }
		}
		# No entry in linkage means entry in userlinkage.
		elsif ( $ctl-&gt;[CTL_DEST] == CTL_DEST_ARRAY ) {
		    if ( defined $userlinkage-&gt;{$opt} ) {
			print STDERR ("=&gt; push(\@{\$L{$opt}}, \"$arg\")\n")
			    if $debug;
			push (@{$userlinkage-&gt;{$opt}}, $arg);
		    }
		    else {
			print STDERR ("=&gt;\$L{$opt} = [\"$arg\"]\n")
			    if $debug;
			$userlinkage-&gt;{$opt} = [$arg];
		    }
		}
		elsif ( $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ) {
		    if ( defined $userlinkage-&gt;{$opt} ) {
			print STDERR ("=&gt; \$L{$opt}-&gt;{$key} = \"$arg\"\n")
			    if $debug;
			$userlinkage-&gt;{$opt}-&gt;{$key} = $arg;
		    }
		    else {
			print STDERR ("=&gt;\$L{$opt} = {$key =&gt; \"$arg\"}\n")
			    if $debug;
			$userlinkage-&gt;{$opt} = {$key =&gt; $arg};
		    }
		}
		else {
		    if ( $ctl-&gt;[CTL_TYPE] eq '+' ) {
			print STDERR ("=&gt; \$L{$opt} += \"$arg\"\n")
			  if $debug;
			if ( defined $userlinkage-&gt;{$opt} ) {
			    $userlinkage-&gt;{$opt} += $arg;
			}
			else {
			    $userlinkage-&gt;{$opt} = $arg;
			}
		    }
		    else {
			print STDERR ("=&gt;\$L{$opt} = \"$arg\"\n") if $debug;
			$userlinkage-&gt;{$opt} = $arg;
		    }
		}

		$argcnt++;
		last if $argcnt &gt;= $ctl-&gt;[CTL_AMAX] &amp;&amp; $ctl-&gt;[CTL_AMAX] != -1;
		undef($arg);

		# Need more args?
		if ( $argcnt &lt; $ctl-&gt;[CTL_AMIN] ) {
		    if ( @$argv ) {
			if ( ValidValue($ctl, $argv-&gt;[0], 1, $argend, $prefix) ) {
			    $arg = shift(@$argv);
			    if ( $ctl-&gt;[CTL_TYPE] =~ /^[iIo]$/ ) {
				$arg =~ tr/_//d;
				$arg = $ctl-&gt;[CTL_TYPE] eq 'o' &amp;&amp; $arg =~ /^0/
				  ? oct($arg)
				  : 0+$arg
			    }
			    ($key,$arg) = $arg =~ /^([^=]+)=(.*)/
			      if $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH;
			    next;
			}
			warn("Value \"$$argv[0]\" invalid for option $opt\n");
			$error++;
		    }
		    else {
			warn("Insufficient arguments for option $opt\n");
			$error++;
		    }
		}

		# Any more args?
		if ( @$argv &amp;&amp; ValidValue($ctl, $argv-&gt;[0], 0, $argend, $prefix) ) {
		    $arg = shift(@$argv);
		    if ( $ctl-&gt;[CTL_TYPE] =~ /^[iIo]$/ ) {
			$arg =~ tr/_//d;
			$arg = $ctl-&gt;[CTL_TYPE] eq 'o' &amp;&amp; $arg =~ /^0/
			  ? oct($arg)
			  : 0+$arg
		    }
		    ($key,$arg) = $arg =~ /^([^=]+)=(.*)/
		      if $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH;
		    next;
		}
	    }
	}

	# Not an option. Save it if we $PERMUTE and don't have a &lt;&gt;.
	elsif ( $order == $PERMUTE ) {
	    # Try non-options call-back.
	    my $cb;
	    if ( defined ($cb = $linkage{'&lt;&gt;'}) ) {
		print STDERR ("=&gt; &amp;L{$tryopt}(\"$tryopt\")\n")
		  if $debug;
		my $eval_error = do {
		    local $@;
		    local $SIG{__DIE__}  = 'DEFAULT';
		    eval {
			# The arg to &lt;&gt; cannot be the CallBack object
			# since it may be passed to other modules that
			# get confused (e.g., Archive::Tar). Well,
			# it's not relevant for this callback anyway.
			&amp;$cb($tryopt);
		    };
		    $@;
		};
		print STDERR ("=&gt; die($eval_error)\n")
		  if $debug &amp;&amp; $eval_error ne '';
		if ( $eval_error =~ /^!/ ) {
		    if ( $eval_error =~ /^!FINISH\b/ ) {
			$goon = 0;
		    }
		}
		elsif ( $eval_error ne '' ) {
		    warn ($eval_error);
		    $error++;
		}
	    }
	    else {
		print STDERR ("=&gt; saving \"$tryopt\" ",
			      "(not an option, may permute)\n") if $debug;
		push (@ret, $tryopt);
	    }
	    next;
	}

	# ...otherwise, terminate.
	else {
	    # Push this one back and exit.
	    unshift (@$argv, $tryopt);
	    return ($error == 0);
	}

    }

    # Finish.
    if ( @ret &amp;&amp; $order == $PERMUTE ) {
	#  Push back accumulated arguments
	print STDERR ("=&gt; restoring \"", join('" "', @ret), "\"\n")
	    if $debug;
	unshift (@$argv, @ret);
    }

    return ($error == 0);
}

# A readable representation of what's in an optbl.
sub OptCtl ($) {
    my ($v) = @_;
    my @v = map { defined($_) ? ($_) : ("&lt;undef&gt;") } @$v;
    "[".
      join(",",
	   "\"$v[CTL_TYPE]\"",
	   "\"$v[CTL_CNAME]\"",
	   "\"$v[CTL_DEFAULT]\"",
	   ("\$","\@","\%","\&amp;")[$v[CTL_DEST] || 0],
	   $v[CTL_AMIN] || '',
	   $v[CTL_AMAX] || '',
#	   $v[CTL_RANGE] || '',
#	   $v[CTL_REPEAT] || '',
	  ). "]";
}

# Parse an option specification and fill the tables.
sub ParseOptionSpec ($$) {
    my ($opt, $opctl) = @_;

    # Match option spec.
    if ( $opt !~ m;^
		   (
		     # Option name
		     (?: \w+[-\w]* )
		     # Alias names, or "?"
		     (?: \| (?: \? | \w[-\w]* ) )*
		     # Aliases
		     (?: \| (?: [^-|!+=:][^|!+=:]* )? )*
		   )?
		   (
		     # Either modifiers ...
		     [!+]
		     |
		     # ... or a value/dest/repeat specification
		     [=:] [ionfs] [@%]? (?: \{\d*,?\d*\} )?
		     |
		     # ... or an optional-with-default spec
		     : (?: -?\d+ | \+ ) [@%]?
		   )?
		   $;x ) {
	return (undef, "Error in option spec: \"$opt\"\n");
    }

    my ($names, $spec) = ($1, $2);
    $spec = '' unless defined $spec;

    # $orig keeps track of the primary name the user specified.
    # This name will be used for the internal or external linkage.
    # In other words, if the user specifies "FoO|BaR", it will
    # match any case combinations of 'foo' and 'bar', but if a global
    # variable needs to be set, it will be $opt_FoO in the exact case
    # as specified.
    my $orig;

    my @names;
    if ( defined $names ) {
	@names =  split (/\|/, $names);
	$orig = $names[0];
    }
    else {
	@names = ('');
	$orig = '';
    }

    # Construct the opctl entries.
    my $entry;
    if ( $spec eq '' || $spec eq '+' || $spec eq '!' ) {
	# Fields are hard-wired here.
	$entry = [$spec,$orig,undef,CTL_DEST_SCALAR,0,0];
    }
    elsif ( $spec =~ /^:(-?\d+|\+)([@%])?$/ ) {
	my $def = $1;
	my $dest = $2;
	my $type = $def eq '+' ? 'I' : 'i';
	$dest ||= '$';
	$dest = $dest eq '@' ? CTL_DEST_ARRAY
	  : $dest eq '%' ? CTL_DEST_HASH : CTL_DEST_SCALAR;
	# Fields are hard-wired here.
	$entry = [$type,$orig,$def eq '+' ? undef : $def,
		  $dest,0,1];
    }
    else {
	my ($mand, $type, $dest) =
	  $spec =~ /^([=:])([ionfs])([@%])?(\{(\d+)?(,)?(\d+)?\})?$/;
	return (undef, "Cannot repeat while bundling: \"$opt\"\n")
	  if $bundling &amp;&amp; defined($4);
	my ($mi, $cm, $ma) = ($5, $6, $7);
	return (undef, "{0} is useless in option spec: \"$opt\"\n")
	  if defined($mi) &amp;&amp; !$mi &amp;&amp; !defined($ma) &amp;&amp; !defined($cm);

	$type = 'i' if $type eq 'n';
	$dest ||= '$';
	$dest = $dest eq '@' ? CTL_DEST_ARRAY
	  : $dest eq '%' ? CTL_DEST_HASH : CTL_DEST_SCALAR;
	# Default minargs to 1/0 depending on mand status.
	$mi = $mand eq '=' ? 1 : 0 unless defined $mi;
	# Adjust mand status according to minargs.
	$mand = $mi ? '=' : ':';
	# Adjust maxargs.
	$ma = $mi ? $mi : 1 unless defined $ma || defined $cm;
	return (undef, "Max must be greater than zero in option spec: \"$opt\"\n")
	  if defined($ma) &amp;&amp; !$ma;
	return (undef, "Max less than min in option spec: \"$opt\"\n")
	  if defined($ma) &amp;&amp; $ma &lt; $mi;

	# Fields are hard-wired here.
	$entry = [$type,$orig,undef,$dest,$mi,$ma||-1];
    }

    # Process all names. First is canonical, the rest are aliases.
    my $dups = '';
    foreach ( @names ) {

	$_ = lc ($_)
	  if $ignorecase &gt; (($bundling &amp;&amp; length($_) == 1) ? 1 : 0);

	if ( exists $opctl-&gt;{$_} ) {
	    $dups .= "Duplicate specification \"$opt\" for option \"$_\"\n";
	}

	if ( $spec eq '!' ) {
	    $opctl-&gt;{"no$_"} = $entry;
	    $opctl-&gt;{"no-$_"} = $entry;
	    $opctl-&gt;{$_} = [@$entry];
	    $opctl-&gt;{$_}-&gt;[CTL_TYPE] = '';
	}
	else {
	    $opctl-&gt;{$_} = $entry;
	}
    }

    if ( $dups &amp;&amp; $^W ) {
	foreach ( split(/\n+/, $dups) ) {
	    warn($_."\n");
	}
    }
    ($names[0], $orig);
}

# Option lookup.
sub FindOption ($$$$$) {

    # returns (1, $opt, $ctl, $arg, $key) if okay,
    # returns (1, undef) if option in error,
    # returns (0) otherwise.

    my ($argv, $prefix, $argend, $opt, $opctl) = @_;

    print STDERR ("=&gt; find \"$opt\"\n") if $debug;

    return (0) unless defined($opt);
    return (0) unless $opt =~ /^($prefix)(.*)$/s;
    return (0) if $opt eq "-" &amp;&amp; !defined $opctl-&gt;{''};

    $opt = substr( $opt, length($1) ); # retain taintedness
    my $starter = $1;

    print STDERR ("=&gt; split \"$starter\"+\"$opt\"\n") if $debug;

    my $optarg;			# value supplied with --opt=value
    my $rest;			# remainder from unbundling

    # If it is a long option, it may include the value.
    # With getopt_compat, only if not bundling.
    if ( ($starter=~/^$longprefix$/
	  || ($getopt_compat &amp;&amp; ($bundling == 0 || $bundling == 2)))
	 &amp;&amp; (my $oppos = index($opt, '=', 1)) &gt; 0) {
	my $optorg = $opt;
	$opt = substr($optorg, 0, $oppos);
	$optarg = substr($optorg, $oppos + 1); # retain tainedness
	print STDERR ("=&gt; option \"", $opt,
		      "\", optarg = \"$optarg\"\n") if $debug;
    }

    #### Look it up ###

    my $tryopt = $opt;		# option to try

    if ( ( $bundling || $bundling_values ) &amp;&amp; $starter eq '-' ) {

	# To try overrides, obey case ignore.
	$tryopt = $ignorecase ? lc($opt) : $opt;

	# If bundling == 2, long options can override bundles.
	if ( $bundling == 2 &amp;&amp; length($tryopt) &gt; 1
	     &amp;&amp; defined ($opctl-&gt;{$tryopt}) ) {
	    print STDERR ("=&gt; $starter$tryopt overrides unbundling\n")
	      if $debug;
	}

	# If bundling_values, option may be followed by the value.
	elsif ( $bundling_values ) {
	    $tryopt = $opt;
	    # Unbundle single letter option.
	    $rest = length ($tryopt) &gt; 0 ? substr ($tryopt, 1) : '';
	    $tryopt = substr ($tryopt, 0, 1);
	    $tryopt = lc ($tryopt) if $ignorecase &gt; 1;
	    print STDERR ("=&gt; $starter$tryopt unbundled from ",
			  "$starter$tryopt$rest\n") if $debug;
	    # Whatever remains may not be considered an option.
	    $optarg = $rest eq '' ? undef : $rest;
	    $rest = undef;
	}

	# Split off a single letter and leave the rest for
	# further processing.
	else {
	    $tryopt = $opt;
	    # Unbundle single letter option.
	    $rest = length ($tryopt) &gt; 0 ? substr ($tryopt, 1) : '';
	    $tryopt = substr ($tryopt, 0, 1);
	    $tryopt = lc ($tryopt) if $ignorecase &gt; 1;
	    print STDERR ("=&gt; $starter$tryopt unbundled from ",
			  "$starter$tryopt$rest\n") if $debug;
	    $rest = undef unless $rest ne '';
	}
    }

    # Try auto-abbreviation.
    elsif ( $autoabbrev &amp;&amp; $opt ne "" ) {
	# Sort the possible long option names.
	my @names = sort(keys (%$opctl));
	# Downcase if allowed.
	$opt = lc ($opt) if $ignorecase;
	$tryopt = $opt;
	# Turn option name into pattern.
	my $pat = quotemeta ($opt);
	# Look up in option names.
	my @hits = grep (/^$pat/, @names);
	print STDERR ("=&gt; ", scalar(@hits), " hits (@hits) with \"$pat\" ",
		      "out of ", scalar(@names), "\n") if $debug;

	# Check for ambiguous results.
	unless ( (@hits &lt;= 1) || (grep ($_ eq $opt, @hits) == 1) ) {
	    # See if all matches are for the same option.
	    my %hit;
	    foreach ( @hits ) {
		my $hit = $opctl-&gt;{$_}-&gt;[CTL_CNAME]
		  if defined $opctl-&gt;{$_}-&gt;[CTL_CNAME];
		$hit = "no" . $hit if $opctl-&gt;{$_}-&gt;[CTL_TYPE] eq '!';
		$hit{$hit} = 1;
	    }
	    # Remove auto-supplied options (version, help).
	    if ( keys(%hit) == 2 ) {
		if ( $auto_version &amp;&amp; exists($hit{version}) ) {
		    delete $hit{version};
		}
		elsif ( $auto_help &amp;&amp; exists($hit{help}) ) {
		    delete $hit{help};
		}
	    }
	    # Now see if it really is ambiguous.
	    unless ( keys(%hit) == 1 ) {
		return (0) if $passthrough;
		warn ("Option ", $opt, " is ambiguous (",
		      join(", ", @hits), ")\n");
		$error++;
		return (1, undef);
	    }
	    @hits = keys(%hit);
	}

	# Complete the option name, if appropriate.
	if ( @hits == 1 &amp;&amp; $hits[0] ne $opt ) {
	    $tryopt = $hits[0];
	    $tryopt = lc ($tryopt)
	      if $ignorecase &gt; (($bundling &amp;&amp; length($tryopt) == 1) ? 1 : 0);
	    print STDERR ("=&gt; option \"$opt\" -&gt; \"$tryopt\"\n")
		if $debug;
	}
    }

    # Map to all lowercase if ignoring case.
    elsif ( $ignorecase ) {
	$tryopt = lc ($opt);
    }

    # Check validity by fetching the info.
    my $ctl = $opctl-&gt;{$tryopt};
    unless  ( defined $ctl ) {
	return (0) if $passthrough;
	# Pretend one char when bundling.
	if ( $bundling == 1 &amp;&amp; length($starter) == 1 ) {
	    $opt = substr($opt,0,1);
            unshift (@$argv, $starter.$rest) if defined $rest;
	}
	if ( $opt eq "" ) {
	    warn ("Missing option after ", $starter, "\n");
	}
	else {
	    warn ("Unknown option: ", $opt, "\n");
	}
	$error++;
	return (1, undef);
    }
    # Apparently valid.
    $opt = $tryopt;
    print STDERR ("=&gt; found ", OptCtl($ctl),
		  " for \"", $opt, "\"\n") if $debug;

    #### Determine argument status ####

    # If it is an option w/o argument, we're almost finished with it.
    my $type = $ctl-&gt;[CTL_TYPE];
    my $arg;

    if ( $type eq '' || $type eq '!' || $type eq '+' ) {
	if ( defined $optarg ) {
	    return (0) if $passthrough;
	    warn ("Option ", $opt, " does not take an argument\n");
	    $error++;
	    undef $opt;
	    undef $optarg if $bundling_values;
	}
	elsif ( $type eq '' || $type eq '+' ) {
	    # Supply explicit value.
	    $arg = 1;
	}
	else {
	    $opt =~ s/^no-?//i;	# strip NO prefix
	    $arg = 0;		# supply explicit value
	}
	unshift (@$argv, $starter.$rest) if defined $rest;
	return (1, $opt, $ctl, $arg);
    }

    # Get mandatory status and type info.
    my $mand = $ctl-&gt;[CTL_AMIN];

    # Check if there is an option argument available.
    if ( $gnu_compat ) {
	my $optargtype = 0; # none, 1 = empty, 2 = nonempty, 3 = aux
	if ( defined($optarg) ) {
	    $optargtype = (length($optarg) == 0) ? 1 : 2;
	}
	elsif ( defined $rest || @$argv &gt; 0 ) {
	    # GNU getopt_long() does not accept the (optional)
	    # argument to be passed to the option without = sign.
	    # We do, since not doing so breaks existing scripts.
	    $optargtype = 3;
	}
	if(($optargtype == 0) &amp;&amp; !$mand) {
	    if ( $type eq 'I' ) {
		# Fake incremental type.
		my @c = @$ctl;
		$c[CTL_TYPE] = '+';
		return (1, $opt, \@c, 1);
	    }
	    my $val
	      = defined($ctl-&gt;[CTL_DEFAULT]) ? $ctl-&gt;[CTL_DEFAULT]
	      : $type eq 's'                 ? ''
	      :                                0;
	    return (1, $opt, $ctl, $val);
	}
	return (1, $opt, $ctl, $type eq 's' ? '' : 0)
	  if $optargtype == 1;  # --foo=  -&gt; return nothing
    }

    # Check if there is an option argument available.
    if ( defined $optarg
	 ? ($optarg eq '')
	 : !(defined $rest || @$argv &gt; 0) ) {
	# Complain if this option needs an argument.
#	if ( $mand &amp;&amp; !($type eq 's' ? defined($optarg) : 0) ) {
	if ( $mand ) {
	    return (0) if $passthrough;
	    warn ("Option ", $opt, " requires an argument\n");
	    $error++;
	    return (1, undef);
	}
	if ( $type eq 'I' ) {
	    # Fake incremental type.
	    my @c = @$ctl;
	    $c[CTL_TYPE] = '+';
	    return (1, $opt, \@c, 1);
	}
	return (1, $opt, $ctl,
		defined($ctl-&gt;[CTL_DEFAULT]) ? $ctl-&gt;[CTL_DEFAULT] :
		$type eq 's' ? '' : 0);
    }

    # Get (possibly optional) argument.
    $arg = (defined $rest ? $rest
	    : (defined $optarg ? $optarg : shift (@$argv)));

    # Get key if this is a "name=value" pair for a hash option.
    my $key;
    if ($ctl-&gt;[CTL_DEST] == CTL_DEST_HASH &amp;&amp; defined $arg) {
	($key, $arg) = ($arg =~ /^([^=]*)=(.*)$/s) ? ($1, $2)
	  : ($arg, defined($ctl-&gt;[CTL_DEFAULT]) ? $ctl-&gt;[CTL_DEFAULT] :
	     ($mand ? undef : ($type eq 's' ? "" : 1)));
	if (! defined $arg) {
	    warn ("Option $opt, key \"$key\", requires a value\n");
	    $error++;
	    # Push back.
	    unshift (@$argv, $starter.$rest) if defined $rest;
	    return (1, undef);
	}
    }

    #### Check if the argument is valid for this option ####

    my $key_valid = $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ? "[^=]+=" : "";

    if ( $type eq 's' ) {	# string
	# A mandatory string takes anything.
	return (1, $opt, $ctl, $arg, $key) if $mand;

	# Same for optional string as a hash value
	return (1, $opt, $ctl, $arg, $key)
	  if $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH;

	# An optional string takes almost anything.
	return (1, $opt, $ctl, $arg, $key)
	  if defined $optarg || defined $rest;
	return (1, $opt, $ctl, $arg, $key) if $arg eq "-"; # ??

	# Check for option or option list terminator.
	if ($arg eq $argend ||
	    $arg =~ /^$prefix.+/) {
	    # Push back.
	    unshift (@$argv, $arg);
	    # Supply empty value.
	    $arg = '';
	}
    }

    elsif ( $type eq 'i'	# numeric/integer
            || $type eq 'I'	# numeric/integer w/ incr default
	    || $type eq 'o' ) { # dec/oct/hex/bin value

	my $o_valid = $type eq 'o' ? PAT_XINT : PAT_INT;

	if ( $bundling &amp;&amp; defined $rest
	     &amp;&amp; $rest =~ /^($key_valid)($o_valid)(.*)$/si ) {
	    ($key, $arg, $rest) = ($1, $2, $+);
	    chop($key) if $key;
	    $arg = ($type eq 'o' &amp;&amp; $arg =~ /^0/) ? oct($arg) : 0+$arg;
	    unshift (@$argv, $starter.$rest) if defined $rest &amp;&amp; $rest ne '';
	}
	elsif ( $arg =~ /^$o_valid$/si ) {
	    $arg =~ tr/_//d;
	    $arg = ($type eq 'o' &amp;&amp; $arg =~ /^0/) ? oct($arg) : 0+$arg;
	}
	else {
	    if ( defined $optarg || $mand ) {
		if ( $passthrough ) {
		    unshift (@$argv, defined $rest ? $starter.$rest : $arg)
		      unless defined $optarg;
		    return (0);
		}
		warn ("Value \"", $arg, "\" invalid for option ",
		      $opt, " (",
		      $type eq 'o' ? "extended " : '',
		      "number expected)\n");
		$error++;
		# Push back.
		unshift (@$argv, $starter.$rest) if defined $rest;
		return (1, undef);
	    }
	    else {
		# Push back.
		unshift (@$argv, defined $rest ? $starter.$rest : $arg);
		if ( $type eq 'I' ) {
		    # Fake incremental type.
		    my @c = @$ctl;
		    $c[CTL_TYPE] = '+';
		    return (1, $opt, \@c, 1);
		}
		# Supply default value.
		$arg = defined($ctl-&gt;[CTL_DEFAULT]) ? $ctl-&gt;[CTL_DEFAULT] : 0;
	    }
	}
    }

    elsif ( $type eq 'f' ) { # real number, int is also ok
	my $o_valid = PAT_FLOAT;
	if ( $bundling &amp;&amp; defined $rest &amp;&amp;
	     $rest =~ /^($key_valid)($o_valid)(.*)$/s ) {
	    $arg =~ tr/_//d;
	    ($key, $arg, $rest) = ($1, $2, $+);
	    chop($key) if $key;
	    unshift (@$argv, $starter.$rest) if defined $rest &amp;&amp; $rest ne '';
	}
	elsif ( $arg =~ /^$o_valid$/ ) {
	    $arg =~ tr/_//d;
	}
	else {
	    if ( defined $optarg || $mand ) {
		if ( $passthrough ) {
		    unshift (@$argv, defined $rest ? $starter.$rest : $arg)
		      unless defined $optarg;
		    return (0);
		}
		warn ("Value \"", $arg, "\" invalid for option ",
		      $opt, " (real number expected)\n");
		$error++;
		# Push back.
		unshift (@$argv, $starter.$rest) if defined $rest;
		return (1, undef);
	    }
	    else {
		# Push back.
		unshift (@$argv, defined $rest ? $starter.$rest : $arg);
		# Supply default value.
		$arg = 0.0;
	    }
	}
    }
    else {
	die("Getopt::Long internal error (Can't happen)\n");
    }
    return (1, $opt, $ctl, $arg, $key);
}

sub ValidValue ($$$$$) {
    my ($ctl, $arg, $mand, $argend, $prefix) = @_;

    if ( $ctl-&gt;[CTL_DEST] == CTL_DEST_HASH ) {
	return 0 unless $arg =~ /[^=]+=(.*)/;
	$arg = $1;
    }

    my $type = $ctl-&gt;[CTL_TYPE];

    if ( $type eq 's' ) {	# string
	# A mandatory string takes anything.
	return (1) if $mand;

	return (1) if $arg eq "-";

	# Check for option or option list terminator.
	return 0 if $arg eq $argend || $arg =~ /^$prefix.+/;
	return 1;
    }

    elsif ( $type eq 'i'	# numeric/integer
            || $type eq 'I'	# numeric/integer w/ incr default
	    || $type eq 'o' ) { # dec/oct/hex/bin value

	my $o_valid = $type eq 'o' ? PAT_XINT : PAT_INT;
	return $arg =~ /^$o_valid$/si;
    }

    elsif ( $type eq 'f' ) { # real number, int is also ok
	my $o_valid = PAT_FLOAT;
	return $arg =~ /^$o_valid$/;
    }
    die("ValidValue: Cannot happen\n");
}

# Getopt::Long Configuration.
sub Configure (@) {
    my (@options) = @_;

    my $prevconfig =
      [ $error, $debug, $major_version, $minor_version, $caller,
	$autoabbrev, $getopt_compat, $ignorecase, $bundling, $order,
	$gnu_compat, $passthrough, $genprefix, $auto_version, $auto_help,
	$longprefix, $bundling_values ];

    if ( ref($options[0]) eq 'ARRAY' ) {
	( $error, $debug, $major_version, $minor_version, $caller,
	  $autoabbrev, $getopt_compat, $ignorecase, $bundling, $order,
	  $gnu_compat, $passthrough, $genprefix, $auto_version, $auto_help,
	  $longprefix, $bundling_values ) = @{shift(@options)};
    }

    my $opt;
    foreach $opt ( @options ) {
	my $try = lc ($opt);
	my $action = 1;
	if ( $try =~ /^no_?(.*)$/s ) {
	    $action = 0;
	    $try = $+;
	}
	if ( ($try eq 'default' or $try eq 'defaults') &amp;&amp; $action ) {
	    ConfigDefaults ();
	}
	elsif ( ($try eq 'posix_default' or $try eq 'posix_defaults') ) {
	    local $ENV{POSIXLY_CORRECT};
	    $ENV{POSIXLY_CORRECT} = 1 if $action;
	    ConfigDefaults ();
	}
	elsif ( $try eq 'auto_abbrev' or $try eq 'autoabbrev' ) {
	    $autoabbrev = $action;
	}
	elsif ( $try eq 'getopt_compat' ) {
	    $getopt_compat = $action;
            $genprefix = $action ? "(--|-|\\+)" : "(--|-)";
	}
	elsif ( $try eq 'gnu_getopt' ) {
	    if ( $action ) {
		$gnu_compat = 1;
		$bundling = 1;
		$getopt_compat = 0;
                $genprefix = "(--|-)";
		$order = $PERMUTE;
		$bundling_values = 0;
	    }
	}
	elsif ( $try eq 'gnu_compat' ) {
	    $gnu_compat = $action;
	    $bundling = 0;
	    $bundling_values = 1;
	}
	elsif ( $try =~ /^(auto_?)?version$/ ) {
	    $auto_version = $action;
	}
	elsif ( $try =~ /^(auto_?)?help$/ ) {
	    $auto_help = $action;
	}
	elsif ( $try eq 'ignorecase' or $try eq 'ignore_case' ) {
	    $ignorecase = $action;
	}
	elsif ( $try eq 'ignorecase_always' or $try eq 'ignore_case_always' ) {
	    $ignorecase = $action ? 2 : 0;
	}
	elsif ( $try eq 'bundling' ) {
	    $bundling = $action;
	    $bundling_values = 0 if $action;
	}
	elsif ( $try eq 'bundling_override' ) {
	    $bundling = $action ? 2 : 0;
	    $bundling_values = 0 if $action;
	}
	elsif ( $try eq 'bundling_values' ) {
	    $bundling_values = $action;
	    $bundling = 0 if $action;
	}
	elsif ( $try eq 'require_order' ) {
	    $order = $action ? $REQUIRE_ORDER : $PERMUTE;
	}
	elsif ( $try eq 'permute' ) {
	    $order = $action ? $PERMUTE : $REQUIRE_ORDER;
	}
	elsif ( $try eq 'pass_through' or $try eq 'passthrough' ) {
	    $passthrough = $action;
	}
	elsif ( $try =~ /^prefix=(.+)$/ &amp;&amp; $action ) {
	    $genprefix = $1;
	    # Turn into regexp. Needs to be parenthesized!
	    $genprefix = "(" . quotemeta($genprefix) . ")";
	    eval { '' =~ /$genprefix/; };
	    die("Getopt::Long: invalid pattern \"$genprefix\"\n") if $@;
	}
	elsif ( $try =~ /^prefix_pattern=(.+)$/ &amp;&amp; $action ) {
	    $genprefix = $1;
	    # Parenthesize if needed.
	    $genprefix = "(" . $genprefix . ")"
	      unless $genprefix =~ /^\(.*\)$/;
	    eval { '' =~ m"$genprefix"; };
	    die("Getopt::Long: invalid pattern \"$genprefix\"\n") if $@;
	}
	elsif ( $try =~ /^long_prefix_pattern=(.+)$/ &amp;&amp; $action ) {
	    $longprefix = $1;
	    # Parenthesize if needed.
	    $longprefix = "(" . $longprefix . ")"
	      unless $longprefix =~ /^\(.*\)$/;
	    eval { '' =~ m"$longprefix"; };
	    die("Getopt::Long: invalid long prefix pattern \"$longprefix\"\n") if $@;
	}
	elsif ( $try eq 'debug' ) {
	    $debug = $action;
	}
	else {
	    die("Getopt::Long: unknown or erroneous config parameter \"$opt\"\n")
	}
    }
    $prevconfig;
}

# Deprecated name.
sub config (@) {
    Configure (@_);
}

# Issue a standard message for --version.
#
# The arguments are mostly the same as for Pod::Usage::pod2usage:
#
#  - a number (exit value)
#  - a string (lead in message)
#  - a hash with options. See Pod::Usage for details.
#
sub VersionMessage(@) {
    # Massage args.
    my $pa = setup_pa_args("version", @_);

    my $v = $main::VERSION;
    my $fh = $pa-&gt;{-output} ||
      ( ($pa-&gt;{-exitval} eq "NOEXIT" || $pa-&gt;{-exitval} &lt; 2) ? \*STDOUT : \*STDERR );

    print $fh (defined($pa-&gt;{-message}) ? $pa-&gt;{-message} : (),
	       $0, defined $v ? " version $v" : (),
	       "\n",
	       "(", __PACKAGE__, "::", "GetOptions",
	       " version ",
	       defined($Getopt::Long::VERSION_STRING)
	         ? $Getopt::Long::VERSION_STRING : $VERSION, ";",
	       " Perl version ",
	       $] &gt;= 5.006 ? sprintf("%vd", $^V) : $],
	       ")\n");
    exit($pa-&gt;{-exitval}) unless $pa-&gt;{-exitval} eq "NOEXIT";
}

# Issue a standard message for --help.
#
# The arguments are the same as for Pod::Usage::pod2usage:
#
#  - a number (exit value)
#  - a string (lead in message)
#  - a hash with options. See Pod::Usage for details.
#
sub HelpMessage(@) {
    eval {
	require Pod::Usage;
	import Pod::Usage;
	1;
    } || die("Cannot provide help: cannot load Pod::Usage\n");

    # Note that pod2usage will issue a warning if -exitval =&gt; NOEXIT.
    pod2usage(setup_pa_args("help", @_));

}

# Helper routine to set up a normalized hash ref to be used as
# argument to pod2usage.
sub setup_pa_args($@) {
    my $tag = shift;		# who's calling

    # If called by direct binding to an option, it will get the option
    # name and value as arguments. Remove these, if so.
    @_ = () if @_ == 2 &amp;&amp; $_[0] eq $tag;

    my $pa;
    if ( @_ &gt; 1 ) {
	$pa = { @_ };
    }
    else {
	$pa = shift || {};
    }

    # At this point, $pa can be a number (exit value), string
    # (message) or hash with options.

    if ( UNIVERSAL::isa($pa, 'HASH') ) {
	# Get rid of -msg vs. -message ambiguity.
	$pa-&gt;{-message} = $pa-&gt;{-msg};
	delete($pa-&gt;{-msg});
    }
    elsif ( $pa =~ /^-?\d+$/ ) {
	$pa = { -exitval =&gt; $pa };
    }
    else {
	$pa = { -message =&gt; $pa };
    }

    # These are _our_ defaults.
    $pa-&gt;{-verbose} = 0 unless exists($pa-&gt;{-verbose});
    $pa-&gt;{-exitval} = 0 unless exists($pa-&gt;{-exitval});
    $pa;
}

# Sneak way to know what version the user requested.
sub VERSION {
    $requested_version = $_[1];
    shift-&gt;SUPER::VERSION(@_);
}

package Getopt::Long::CallBack;

sub new {
    my ($pkg, %atts) = @_;
    bless { %atts }, $pkg;
}

sub name {
    my $self = shift;
    ''.$self-&gt;{name};
}

use overload
  # Treat this object as an ordinary string for legacy API.
  '""'	   =&gt; \&amp;name,
  fallback =&gt; 1;

1;

################ Documentation ################

=head1 NAME

Getopt::Long - Extended processing of command line options

=head1 SYNOPSIS

  use Getopt::Long;
  my $data   = "file.dat";
  my $length = 24;
  my $verbose;
  GetOptions ("length=i" =&gt; \$length,    # numeric
              "file=s"   =&gt; \$data,      # string
              "verbose"  =&gt; \$verbose)   # flag
  or die("Error in command line arguments\n");

=head1 DESCRIPTION

The Getopt::Long module implements an extended getopt function called
GetOptions(). It parses the command line from C&lt;@ARGV&gt;, recognizing
and removing specified options and their possible values.

This function adheres to the POSIX syntax for command
line options, with GNU extensions. In general, this means that options
have long names instead of single letters, and are introduced with a
double dash "--". Support for bundling of command line options, as was
the case with the more traditional single-letter approach, is provided
but not enabled by default.

=head1 Command Line Options, an Introduction

Command line operated programs traditionally take their arguments from
the command line, for example filenames or other information that the
program needs to know. Besides arguments, these programs often take
command line I&lt;options&gt; as well. Options are not necessary for the
program to work, hence the name 'option', but are used to modify its
default behaviour. For example, a program could do its job quietly,
but with a suitable option it could provide verbose information about
what it did.

Command line options come in several flavours. Historically, they are
preceded by a single dash C&lt;-&gt;, and consist of a single letter.

    -l -a -c

Usually, these single-character options can be bundled:

    -lac

Options can have values, the value is placed after the option
character. Sometimes with whitespace in between, sometimes not:

    -s 24 -s24

Due to the very cryptic nature of these options, another style was
developed that used long names. So instead of a cryptic C&lt;-l&gt; one
could use the more descriptive C&lt;--long&gt;. To distinguish between a
bundle of single-character options and a long one, two dashes are used
to precede the option name. Early implementations of long options used
a plus C&lt;+&gt; instead. Also, option values could be specified either
like

    --size=24

or

    --size 24

The C&lt;+&gt; form is now obsolete and strongly deprecated.

=head1 Getting Started with Getopt::Long

Getopt::Long is the Perl5 successor of C&lt;newgetopt.pl&gt;. This was the
first Perl module that provided support for handling the new style of
command line options, in particular long option names, hence the Perl5
name Getopt::Long. This module also supports single-character options
and bundling.

To use Getopt::Long from a Perl program, you must include the
following line in your Perl program:

    use Getopt::Long;

This will load the core of the Getopt::Long module and prepare your
program for using it. Most of the actual Getopt::Long code is not
loaded until you really call one of its functions.

In the default configuration, options names may be abbreviated to
uniqueness, case does not matter, and a single dash is sufficient,
even for long option names. Also, options may be placed between
non-option arguments. See L&lt;Configuring Getopt::Long&gt; for more
details on how to configure Getopt::Long.

=head2 Simple options

The most simple options are the ones that take no values. Their mere
presence on the command line enables the option. Popular examples are:

    --all --verbose --quiet --debug

Handling simple options is straightforward:

    my $verbose = '';	# option variable with default value (false)
    my $all = '';	# option variable with default value (false)
    GetOptions ('verbose' =&gt; \$verbose, 'all' =&gt; \$all);

The call to GetOptions() parses the command line arguments that are
present in C&lt;@ARGV&gt; and sets the option variable to the value C&lt;1&gt; if
the option did occur on the command line. Otherwise, the option
variable is not touched. Setting the option value to true is often
called I&lt;enabling&gt; the option.

The option name as specified to the GetOptions() function is called
the option I&lt;specification&gt;. Later we'll see that this specification
can contain more than just the option name. The reference to the
variable is called the option I&lt;destination&gt;.

GetOptions() will return a true value if the command line could be
processed successfully. Otherwise, it will write error messages using
die() and warn(), and return a false result.

=head2 A little bit less simple options

Getopt::Long supports two useful variants of simple options:
I&lt;negatable&gt; options and I&lt;incremental&gt; options.

A negatable option is specified with an exclamation mark C&lt;!&gt; after the
option name:

    my $verbose = '';	# option variable with default value (false)
    GetOptions ('verbose!' =&gt; \$verbose);

Now, using C&lt;--verbose&gt; on the command line will enable C&lt;$verbose&gt;,
as expected. But it is also allowed to use C&lt;--noverbose&gt;, which will
disable C&lt;$verbose&gt; by setting its value to C&lt;0&gt;. Using a suitable
default value, the program can find out whether C&lt;$verbose&gt; is false
by default, or disabled by using C&lt;--noverbose&gt;.

An incremental option is specified with a plus C&lt;+&gt; after the
option name:

    my $verbose = '';	# option variable with default value (false)
    GetOptions ('verbose+' =&gt; \$verbose);

Using C&lt;--verbose&gt; on the command line will increment the value of
C&lt;$verbose&gt;. This way the program can keep track of how many times the
option occurred on the command line. For example, each occurrence of
C&lt;--verbose&gt; could increase the verbosity level of the program.

=head2 Mixing command line option with other arguments

Usually programs take command line options as well as other arguments,
for example, file names. It is good practice to always specify the
options first, and the other arguments last. Getopt::Long will,
however, allow the options and arguments to be mixed and 'filter out'
all the options before passing the rest of the arguments to the
program. To stop Getopt::Long from processing further arguments,
insert a double dash C&lt;--&gt; on the command line:

    --size 24 -- --all

In this example, C&lt;--all&gt; will I&lt;not&gt; be treated as an option, but
passed to the program unharmed, in C&lt;@ARGV&gt;.

=head2 Options with values

For options that take values it must be specified whether the option
value is required or not, and what kind of value the option expects.

Three kinds of values are supported: integer numbers, floating point
numbers, and strings.

If the option value is required, Getopt::Long will take the
command line argument that follows the option and assign this to the
option variable. If, however, the option value is specified as
optional, this will only be done if that value does not look like a
valid command line option itself.

    my $tag = '';	# option variable with default value
    GetOptions ('tag=s' =&gt; \$tag);

In the option specification, the option name is followed by an equals
sign C&lt;=&gt; and the letter C&lt;s&gt;. The equals sign indicates that this
option requires a value. The letter C&lt;s&gt; indicates that this value is
an arbitrary string. Other possible value types are C&lt;i&gt; for integer
values, and C&lt;f&gt; for floating point values. Using a colon C&lt;:&gt; instead
of the equals sign indicates that the option value is optional. In
this case, if no suitable value is supplied, string valued options get
an empty string C&lt;''&gt; assigned, while numeric options are set to C&lt;0&gt;.

=head2 Options with multiple values

Options sometimes take several values. For example, a program could
use multiple directories to search for library files:

    --library lib/stdlib --library lib/extlib

To accomplish this behaviour, simply specify an array reference as the
destination for the option:

    GetOptions ("library=s" =&gt; \@libfiles);

Alternatively, you can specify that the option can have multiple
values by adding a "@", and pass a reference to a scalar as the
destination:

    GetOptions ("library=s@" =&gt; \$libfiles);

Used with the example above, C&lt;@libfiles&gt; c.q. C&lt;@$libfiles&gt; would
contain two strings upon completion: C&lt;"lib/stdlib"&gt; and
C&lt;"lib/extlib"&gt;, in that order. It is also possible to specify that
only integer or floating point numbers are acceptable values.

Often it is useful to allow comma-separated lists of values as well as
multiple occurrences of the options. This is easy using Perl's split()
and join() operators:

    GetOptions ("library=s" =&gt; \@libfiles);
    @libfiles = split(/,/,join(',',@libfiles));

Of course, it is important to choose the right separator string for
each purpose.

Warning: What follows is an experimental feature.

Options can take multiple values at once, for example

    --coordinates 52.2 16.4 --rgbcolor 255 255 149

This can be accomplished by adding a repeat specifier to the option
specification. Repeat specifiers are very similar to the C&lt;{...}&gt;
repeat specifiers that can be used with regular expression patterns.
For example, the above command line would be handled as follows:

    GetOptions('coordinates=f{2}' =&gt; \@coor, 'rgbcolor=i{3}' =&gt; \@color);

The destination for the option must be an array or array reference.

It is also possible to specify the minimal and maximal number of
arguments an option takes. C&lt;foo=s{2,4}&gt; indicates an option that
takes at least two and at most 4 arguments. C&lt;foo=s{1,}&gt; indicates one
or more values; C&lt;foo:s{,}&gt; indicates zero or more option values.

=head2 Options with hash values

If the option destination is a reference to a hash, the option will
take, as value, strings of the form I&lt;key&gt;C&lt;=&gt;I&lt;value&gt;. The value will
be stored with the specified key in the hash.

    GetOptions ("define=s" =&gt; \%defines);

Alternatively you can use:

    GetOptions ("define=s%" =&gt; \$defines);

When used with command line options:

    --define os=linux --define vendor=redhat

the hash C&lt;%defines&gt; (or C&lt;%$defines&gt;) will contain two keys, C&lt;"os"&gt;
with value C&lt;"linux"&gt; and C&lt;"vendor"&gt; with value C&lt;"redhat"&gt;. It is
also possible to specify that only integer or floating point numbers
are acceptable values. The keys are always taken to be strings.

=head2 User-defined subroutines to handle options

Ultimate control over what should be done when (actually: each time)
an option is encountered on the command line can be achieved by
designating a reference to a subroutine (or an anonymous subroutine)
as the option destination. When GetOptions() encounters the option, it
will call the subroutine with two or three arguments. The first
argument is the name of the option. (Actually, it is an object that
stringifies to the name of the option.) For a scalar or array destination,
the second argument is the value to be stored. For a hash destination,
the second argument is the key to the hash, and the third argument
the value to be stored. It is up to the subroutine to store the value,
or do whatever it thinks is appropriate.

A trivial application of this mechanism is to implement options that
are related to each other. For example:

    my $verbose = '';	# option variable with default value (false)
    GetOptions ('verbose' =&gt; \$verbose,
	        'quiet'   =&gt; sub { $verbose = 0 });

Here C&lt;--verbose&gt; and C&lt;--quiet&gt; control the same variable
C&lt;$verbose&gt;, but with opposite values.

If the subroutine needs to signal an error, it should call die() with
the desired error message as its argument. GetOptions() will catch the
die(), issue the error message, and record that an error result must
be returned upon completion.

If the text of the error message starts with an exclamation mark C&lt;!&gt;
it is interpreted specially by GetOptions(). There is currently one
special command implemented: C&lt;die("!FINISH")&gt; will cause GetOptions()
to stop processing options, as if it encountered a double dash C&lt;--&gt;.

In version 2.37 the first argument to the callback function was
changed from string to object. This was done to make room for
extensions and more detailed control. The object stringifies to the
option name so this change should not introduce compatibility
problems.

Here is an example of how to access the option name and value from within
a subroutine:

    GetOptions ('opt=i' =&gt; \&amp;handler);
    sub handler {
        my ($opt_name, $opt_value) = @_;
        print("Option name is $opt_name and value is $opt_value\n");
    }

=head2 Options with multiple names

Often it is user friendly to supply alternate mnemonic names for
options. For example C&lt;--height&gt; could be an alternate name for
C&lt;--length&gt;. Alternate names can be included in the option
specification, separated by vertical bar C&lt;|&gt; characters. To implement
the above example:

    GetOptions ('length|height=f' =&gt; \$length);

The first name is called the I&lt;primary&gt; name, the other names are
called I&lt;aliases&gt;. When using a hash to store options, the key will
always be the primary name.

Multiple alternate names are possible.

=head2 Case and abbreviations

Without additional configuration, GetOptions() will ignore the case of
option names, and allow the options to be abbreviated to uniqueness.

    GetOptions ('length|height=f' =&gt; \$length, "head" =&gt; \$head);

This call will allow C&lt;--l&gt; and C&lt;--L&gt; for the length option, but
requires a least C&lt;--hea&gt; and C&lt;--hei&gt; for the head and height options.

=head2 Summary of Option Specifications

Each option specifier consists of two parts: the name specification
and the argument specification.

The name specification contains the name of the option, optionally
followed by a list of alternative names separated by vertical bar
characters.

    length	      option name is "length"
    length|size|l     name is "length", aliases are "size" and "l"

The argument specification is optional. If omitted, the option is
considered boolean, a value of 1 will be assigned when the option is
used on the command line.

The argument specification can be

=over 4

=item !

The option does not take an argument and may be negated by prefixing
it with "no" or "no-". E.g. C&lt;"foo!"&gt; will allow C&lt;--foo&gt; (a value of
1 will be assigned) as well as C&lt;--nofoo&gt; and C&lt;--no-foo&gt; (a value of
0 will be assigned). If the option has aliases, this applies to the
aliases as well.

Using negation on a single letter option when bundling is in effect is
pointless and will result in a warning.

=item +

The option does not take an argument and will be incremented by 1
every time it appears on the command line. E.g. C&lt;"more+"&gt;, when used
with C&lt;--more --more --more&gt;, will increment the value three times,
resulting in a value of 3 (provided it was 0 or undefined at first).

The C&lt;+&gt; specifier is ignored if the option destination is not a scalar.

=item = I&lt;type&gt; [ I&lt;desttype&gt; ] [ I&lt;repeat&gt; ]

The option requires an argument of the given type. Supported types
are:

=over 4

=item s

String. An arbitrary sequence of characters. It is valid for the
argument to start with C&lt;-&gt; or C&lt;--&gt;.

=item i

Integer. An optional leading plus or minus sign, followed by a
sequence of digits.

=item o

Extended integer, Perl style. This can be either an optional leading
plus or minus sign, followed by a sequence of digits, or an octal
string (a zero, optionally followed by '0', '1', .. '7'), or a
hexadecimal string (C&lt;0x&gt; followed by '0' .. '9', 'a' .. 'f', case
insensitive), or a binary string (C&lt;0b&gt; followed by a series of '0'
and '1').

=item f

Real number. For example C&lt;3.14&gt;, C&lt;-6.23E24&gt; and so on.

=back

The I&lt;desttype&gt; can be C&lt;@&gt; or C&lt;%&gt; to specify that the option is
list or a hash valued. This is only needed when the destination for
the option value is not otherwise specified. It should be omitted when
not needed.

The I&lt;repeat&gt; specifies the number of values this option takes per
occurrence on the command line. It has the format C&lt;{&gt; [ I&lt;min&gt; ] [ C&lt;,&gt; [ I&lt;max&gt; ] ] C&lt;}&gt;.

I&lt;min&gt; denotes the minimal number of arguments. It defaults to 1 for
options with C&lt;=&gt; and to 0 for options with C&lt;:&gt;, see below. Note that
I&lt;min&gt; overrules the C&lt;=&gt; / C&lt;:&gt; semantics.

I&lt;max&gt; denotes the maximum number of arguments. It must be at least
I&lt;min&gt;. If I&lt;max&gt; is omitted, I&lt;but the comma is not&gt;, there is no
upper bound to the number of argument values taken.

=item : I&lt;type&gt; [ I&lt;desttype&gt; ]

Like C&lt;=&gt;, but designates the argument as optional.
If omitted, an empty string will be assigned to string values options,
and the value zero to numeric options.

Note that if a string argument starts with C&lt;-&gt; or C&lt;--&gt;, it will be
considered an option on itself.

=item : I&lt;number&gt; [ I&lt;desttype&gt; ]

Like C&lt;:i&gt;, but if the value is omitted, the I&lt;number&gt; will be assigned.

=item : + [ I&lt;desttype&gt; ]

Like C&lt;:i&gt;, but if the value is omitted, the current value for the
option will be incremented.

=back

=head1 Advanced Possibilities

=head2 Object oriented interface

Getopt::Long can be used in an object oriented way as well:

    use Getopt::Long;
    $p = Getopt::Long::Parser-&gt;new;
    $p-&gt;configure(...configuration options...);
    if ($p-&gt;getoptions(...options descriptions...)) ...
    if ($p-&gt;getoptionsfromarray( \@array, ...options descriptions...)) ...

Configuration options can be passed to the constructor:

    $p = new Getopt::Long::Parser
             config =&gt; [...configuration options...];

=head2 Thread Safety

Getopt::Long is thread safe when using ithreads as of Perl 5.8.  It is
I&lt;not&gt; thread safe when using the older (experimental and now
obsolete) threads implementation that was added to Perl 5.005.

=head2 Documentation and help texts

Getopt::Long encourages the use of Pod::Usage to produce help
messages. For example:

    use Getopt::Long;
    use Pod::Usage;

    my $man = 0;
    my $help = 0;

    GetOptions('help|?' =&gt; \$help, man =&gt; \$man) or pod2usage(2);
    pod2usage(1) if $help;
    pod2usage(-exitval =&gt; 0, -verbose =&gt; 2) if $man;

    __END__

    =head1 NAME

    sample - Using Getopt::Long and Pod::Usage

    =head1 SYNOPSIS

    sample [options] [file ...]

     Options:
       -help            brief help message
       -man             full documentation

    =head1 OPTIONS

    =over 8

    =item B&lt;-help&gt;

    Print a brief help message and exits.

    =item B&lt;-man&gt;

    Prints the manual page and exits.

    =back

    =head1 DESCRIPTION

    B&lt;This program&gt; will read the given input file(s) and do something
    useful with the contents thereof.

    =cut

See L&lt;Pod::Usage&gt; for details.

=head2 Parsing options from an arbitrary array

By default, GetOptions parses the options that are present in the
global array C&lt;@ARGV&gt;. A special entry C&lt;GetOptionsFromArray&gt; can be
used to parse options from an arbitrary array.

    use Getopt::Long qw(GetOptionsFromArray);
    $ret = GetOptionsFromArray(\@myopts, ...);

When used like this, options and their possible values are removed
from C&lt;@myopts&gt;, the global C&lt;@ARGV&gt; is not touched at all.

The following two calls behave identically:

    $ret = GetOptions( ... );
    $ret = GetOptionsFromArray(\@ARGV, ... );

This also means that a first argument hash reference now becomes the
second argument:

    $ret = GetOptions(\%opts, ... );
    $ret = GetOptionsFromArray(\@ARGV, \%opts, ... );

=head2 Parsing options from an arbitrary string

A special entry C&lt;GetOptionsFromString&gt; can be used to parse options
from an arbitrary string.

    use Getopt::Long qw(GetOptionsFromString);
    $ret = GetOptionsFromString($string, ...);

The contents of the string are split into arguments using a call to
C&lt;Text::ParseWords::shellwords&gt;. As with C&lt;GetOptionsFromArray&gt;, the
global C&lt;@ARGV&gt; is not touched.

It is possible that, upon completion, not all arguments in the string
have been processed. C&lt;GetOptionsFromString&gt; will, when called in list
context, return both the return status and an array reference to any
remaining arguments:

    ($ret, $args) = GetOptionsFromString($string, ... );

If any arguments remain, and C&lt;GetOptionsFromString&gt; was not called in
list context, a message will be given and C&lt;GetOptionsFromString&gt; will
return failure.

As with GetOptionsFromArray, a first argument hash reference now
becomes the second argument.

=head2 Storing options values in a hash

Sometimes, for example when there are a lot of options, having a
separate variable for each of them can be cumbersome. GetOptions()
supports, as an alternative mechanism, storing options values in a
hash.

To obtain this, a reference to a hash must be passed I&lt;as the first
argument&gt; to GetOptions(). For each option that is specified on the
command line, the option value will be stored in the hash with the
option name as key. Options that are not actually used on the command
line will not be put in the hash, on other words,
C&lt;exists($h{option})&gt; (or defined()) can be used to test if an option
was used. The drawback is that warnings will be issued if the program
runs under C&lt;use strict&gt; and uses C&lt;$h{option}&gt; without testing with
exists() or defined() first.

    my %h = ();
    GetOptions (\%h, 'length=i');	# will store in $h{length}

For options that take list or hash values, it is necessary to indicate
this by appending an C&lt;@&gt; or C&lt;%&gt; sign after the type:

    GetOptions (\%h, 'colours=s@');	# will push to @{$h{colours}}

To make things more complicated, the hash may contain references to
the actual destinations, for example:

    my $len = 0;
    my %h = ('length' =&gt; \$len);
    GetOptions (\%h, 'length=i');	# will store in $len

This example is fully equivalent with:

    my $len = 0;
    GetOptions ('length=i' =&gt; \$len);	# will store in $len

Any mixture is possible. For example, the most frequently used options
could be stored in variables while all other options get stored in the
hash:

    my $verbose = 0;			# frequently referred
    my $debug = 0;			# frequently referred
    my %h = ('verbose' =&gt; \$verbose, 'debug' =&gt; \$debug);
    GetOptions (\%h, 'verbose', 'debug', 'filter', 'size=i');
    if ( $verbose ) { ... }
    if ( exists $h{filter} ) { ... option 'filter' was specified ... }

=head2 Bundling

With bundling it is possible to set several single-character options
at once. For example if C&lt;a&gt;, C&lt;v&gt; and C&lt;x&gt; are all valid options,

    -vax

will set all three.

Getopt::Long supports three styles of bundling. To enable bundling, a
call to Getopt::Long::Configure is required.

The simplest style of bundling can be enabled with:

    Getopt::Long::Configure ("bundling");

Configured this way, single-character options can be bundled but long
options B&lt;must&gt; always start with a double dash C&lt;--&gt; to avoid
ambiguity. For example, when C&lt;vax&gt;, C&lt;a&gt;, C&lt;v&gt; and C&lt;x&gt; are all valid
options,

    -vax

will set C&lt;a&gt;, C&lt;v&gt; and C&lt;x&gt;, but

    --vax

will set C&lt;vax&gt;.

The second style of bundling lifts this restriction. It can be enabled
with:

    Getopt::Long::Configure ("bundling_override");

Now, C&lt;-vax&gt; will set the option C&lt;vax&gt;.

In all of the above cases, option values may be inserted in the
bundle. For example:

    -h24w80

is equivalent to

    -h 24 -w 80

A third style of bundling allows only values to be bundled with
options. It can be enabled with:

    Getopt::Long::Configure ("bundling_values");

Now, C&lt;-h24&gt; will set the option C&lt;h&gt; to C&lt;24&gt;, but option bundles
like C&lt;-vxa&gt; and C&lt;-h24w80&gt; are flagged as errors.

Enabling C&lt;bundling_values&gt; will disable the other two styles of
bundling.

When configured for bundling, single-character options are matched
case sensitive while long options are matched case insensitive. To
have the single-character options matched case insensitive as well,
use:

    Getopt::Long::Configure ("bundling", "ignorecase_always");

It goes without saying that bundling can be quite confusing.

=head2 The lonesome dash

Normally, a lone dash C&lt;-&gt; on the command line will not be considered
an option. Option processing will terminate (unless "permute" is
configured) and the dash will be left in C&lt;@ARGV&gt;.

It is possible to get special treatment for a lone dash. This can be
achieved by adding an option specification with an empty name, for
example:

    GetOptions ('' =&gt; \$stdio);

A lone dash on the command line will now be a legal option, and using
it will set variable C&lt;$stdio&gt;.

=head2 Argument callback

A special option 'name' C&lt;&lt; &lt;&gt; &gt;&gt; can be used to designate a subroutine
to handle non-option arguments. When GetOptions() encounters an
argument that does not look like an option, it will immediately call this
subroutine and passes it one parameter: the argument name. Well, actually
it is an object that stringifies to the argument name.

For example:

    my $width = 80;
    sub process { ... }
    GetOptions ('width=i' =&gt; \$width, '&lt;&gt;' =&gt; \&amp;process);

When applied to the following command line:

    arg1 --width=72 arg2 --width=60 arg3

This will call
C&lt;process("arg1")&gt; while C&lt;$width&gt; is C&lt;80&gt;,
C&lt;process("arg2")&gt; while C&lt;$width&gt; is C&lt;72&gt;, and
C&lt;process("arg3")&gt; while C&lt;$width&gt; is C&lt;60&gt;.

This feature requires configuration option B&lt;permute&gt;, see section
L&lt;Configuring Getopt::Long&gt;.

=head1 Configuring Getopt::Long

Getopt::Long can be configured by calling subroutine
Getopt::Long::Configure(). This subroutine takes a list of quoted
strings, each specifying a configuration option to be enabled, e.g.
C&lt;ignore_case&gt;, or disabled, e.g. C&lt;no_ignore_case&gt;. Case does not
matter. Multiple calls to Configure() are possible.

Alternatively, as of version 2.24, the configuration options may be
passed together with the C&lt;use&gt; statement:

    use Getopt::Long qw(:config no_ignore_case bundling);

The following options are available:

=over 12

=item default

This option causes all configuration options to be reset to their
default values.

=item posix_default

This option causes all configuration options to be reset to their
default values as if the environment variable POSIXLY_CORRECT had
been set.

=item auto_abbrev

Allow option names to be abbreviated to uniqueness.
Default is enabled unless environment variable
POSIXLY_CORRECT has been set, in which case C&lt;auto_abbrev&gt; is disabled.

=item getopt_compat

Allow C&lt;+&gt; to start options.
Default is enabled unless environment variable
POSIXLY_CORRECT has been set, in which case C&lt;getopt_compat&gt; is disabled.

=item gnu_compat

C&lt;gnu_compat&gt; controls whether C&lt;--opt=&gt; is allowed, and what it should
do. Without C&lt;gnu_compat&gt;, C&lt;--opt=&gt; gives an error. With C&lt;gnu_compat&gt;,
C&lt;--opt=&gt; will give option C&lt;opt&gt; and empty value.
This is the way GNU getopt_long() does it.

Note that C&lt;--opt value&gt; is still accepted, even though GNU
getopt_long() doesn't.

=item gnu_getopt

This is a short way of setting C&lt;gnu_compat&gt; C&lt;bundling&gt; C&lt;permute&gt;
C&lt;no_getopt_compat&gt;. With C&lt;gnu_getopt&gt;, command line handling should be
reasonably compatible with GNU getopt_long().

=item require_order

Whether command line arguments are allowed to be mixed with options.
Default is disabled unless environment variable
POSIXLY_CORRECT has been set, in which case C&lt;require_order&gt; is enabled.

See also C&lt;permute&gt;, which is the opposite of C&lt;require_order&gt;.

=item permute

Whether command line arguments are allowed to be mixed with options.
Default is enabled unless environment variable
POSIXLY_CORRECT has been set, in which case C&lt;permute&gt; is disabled.
Note that C&lt;permute&gt; is the opposite of C&lt;require_order&gt;.

If C&lt;permute&gt; is enabled, this means that

    --foo arg1 --bar arg2 arg3

is equivalent to

    --foo --bar arg1 arg2 arg3

If an argument callback routine is specified, C&lt;@ARGV&gt; will always be
empty upon successful return of GetOptions() since all options have been
processed. The only exception is when C&lt;--&gt; is used:

    --foo arg1 --bar arg2 -- arg3

This will call the callback routine for arg1 and arg2, and then
terminate GetOptions() leaving C&lt;"arg3"&gt; in C&lt;@ARGV&gt;.

If C&lt;require_order&gt; is enabled, options processing
terminates when the first non-option is encountered.

    --foo arg1 --bar arg2 arg3

is equivalent to

    --foo -- arg1 --bar arg2 arg3

If C&lt;pass_through&gt; is also enabled, options processing will terminate
at the first unrecognized option, or non-option, whichever comes
first.

=item bundling (default: disabled)

Enabling this option will allow single-character options to be
bundled. To distinguish bundles from long option names, long options
I&lt;must&gt; be introduced with C&lt;--&gt; and bundles with C&lt;-&gt;.

Note that, if you have options C&lt;a&gt;, C&lt;l&gt; and C&lt;all&gt;, and
auto_abbrev enabled, possible arguments and option settings are:

    using argument               sets option(s)
    ------------------------------------------
    -a, --a                      a
    -l, --l                      l
    -al, -la, -ala, -all,...     a, l
    --al, --all                  all

The surprising part is that C&lt;--a&gt; sets option C&lt;a&gt; (due to auto
completion), not C&lt;all&gt;.

Note: disabling C&lt;bundling&gt; also disables C&lt;bundling_override&gt;.

=item bundling_override (default: disabled)

If C&lt;bundling_override&gt; is enabled, bundling is enabled as with
C&lt;bundling&gt; but now long option names override option bundles.

Note: disabling C&lt;bundling_override&gt; also disables C&lt;bundling&gt;.

B&lt;Note:&gt; Using option bundling can easily lead to unexpected results,
especially when mixing long options and bundles. Caveat emptor.

=item ignore_case  (default: enabled)

If enabled, case is ignored when matching option names. If, however,
bundling is enabled as well, single character options will be treated
case-sensitive.

With C&lt;ignore_case&gt;, option specifications for options that only
differ in case, e.g., C&lt;"foo"&gt; and C&lt;"Foo"&gt;, will be flagged as
duplicates.

Note: disabling C&lt;ignore_case&gt; also disables C&lt;ignore_case_always&gt;.

=item ignore_case_always (default: disabled)

When bundling is in effect, case is ignored on single-character
options also.

Note: disabling C&lt;ignore_case_always&gt; also disables C&lt;ignore_case&gt;.

=item auto_version (default:disabled)

Automatically provide support for the B&lt;--version&gt; option if
the application did not specify a handler for this option itself.

Getopt::Long will provide a standard version message that includes the
program name, its version (if $main::VERSION is defined), and the
versions of Getopt::Long and Perl. The message will be written to
standard output and processing will terminate.

C&lt;auto_version&gt; will be enabled if the calling program explicitly
specified a version number higher than 2.32 in the C&lt;use&gt; or
C&lt;require&gt; statement.

=item auto_help (default:disabled)

Automatically provide support for the B&lt;--help&gt; and B&lt;-?&gt; options if
the application did not specify a handler for this option itself.

Getopt::Long will provide a help message using module L&lt;Pod::Usage&gt;. The
message, derived from the SYNOPSIS POD section, will be written to
standard output and processing will terminate.

C&lt;auto_help&gt; will be enabled if the calling program explicitly
specified a version number higher than 2.32 in the C&lt;use&gt; or
C&lt;require&gt; statement.

=item pass_through (default: disabled)

With C&lt;pass_through&gt; anything that is unknown, ambiguous or supplied with
an invalid option will not be flagged as an error. Instead the unknown
option(s) will be passed to the catchall C&lt;&lt; &lt;&gt; &gt;&gt; if present, otherwise
through to C&lt;@ARGV&gt;. This makes it possible to write wrapper scripts that
process only part of the user supplied command line arguments, and pass the
remaining options to some other program.

If C&lt;require_order&gt; is enabled, options processing will terminate at the
first unrecognized option, or non-option, whichever comes first and all
remaining arguments are passed to C&lt;@ARGV&gt; instead of the catchall
C&lt;&lt; &lt;&gt; &gt;&gt; if present.  However, if C&lt;permute&gt; is enabled instead, results
can become confusing.

Note that the options terminator (default C&lt;--&gt;), if present, will
also be passed through in C&lt;@ARGV&gt;.

=item prefix

The string that starts options. If a constant string is not
sufficient, see C&lt;prefix_pattern&gt;.

=item prefix_pattern

A Perl pattern that identifies the strings that introduce options.
Default is C&lt;--|-|\+&gt; unless environment variable
POSIXLY_CORRECT has been set, in which case it is C&lt;--|-&gt;.

=item long_prefix_pattern

A Perl pattern that allows the disambiguation of long and short
prefixes. Default is C&lt;--&gt;.

Typically you only need to set this if you are using nonstandard
prefixes and want some or all of them to have the same semantics as
'--' does under normal circumstances.

For example, setting prefix_pattern to C&lt;--|-|\+|\/&gt; and
long_prefix_pattern to C&lt;--|\/&gt; would add Win32 style argument
handling.

=item debug (default: disabled)

Enable debugging output.

=back

=head1 Exportable Methods

=over

=item VersionMessage

This subroutine provides a standard version message. Its argument can be:

=over 4

=item *

A string containing the text of a message to print I&lt;before&gt; printing
the standard message.

=item *

A numeric value corresponding to the desired exit status.

=item *

A reference to a hash.

=back

If more than one argument is given then the entire argument list is
assumed to be a hash.  If a hash is supplied (either as a reference or
as a list) it should contain one or more elements with the following
keys:

=over 4

=item C&lt;-message&gt;

=item C&lt;-msg&gt;

The text of a message to print immediately prior to printing the
program's usage message.

=item C&lt;-exitval&gt;

The desired exit status to pass to the B&lt;exit()&gt; function.
This should be an integer, or else the string "NOEXIT" to
indicate that control should simply be returned without
terminating the invoking process.

=item C&lt;-output&gt;

A reference to a filehandle, or the pathname of a file to which the
usage message should be written. The default is C&lt;\*STDERR&gt; unless the
exit value is less than 2 (in which case the default is C&lt;\*STDOUT&gt;).

=back

You cannot tie this routine directly to an option, e.g.:

    GetOptions("version" =&gt; \&amp;VersionMessage);

Use this instead:

    GetOptions("version" =&gt; sub { VersionMessage() });

=item HelpMessage

This subroutine produces a standard help message, derived from the
program's POD section SYNOPSIS using L&lt;Pod::Usage&gt;. It takes the same
arguments as VersionMessage(). In particular, you cannot tie it
directly to an option, e.g.:

    GetOptions("help" =&gt; \&amp;HelpMessage);

Use this instead:

    GetOptions("help" =&gt; sub { HelpMessage() });

=back

=head1 Return values and Errors

Configuration errors and errors in the option definitions are
signalled using die() and will terminate the calling program unless
the call to Getopt::Long::GetOptions() was embedded in C&lt;eval { ...
}&gt;, or die() was trapped using C&lt;$SIG{__DIE__}&gt;.

GetOptions returns true to indicate success.
It returns false when the function detected one or more errors during
option parsing. These errors are signalled using warn() and can be
trapped with C&lt;$SIG{__WARN__}&gt;.

=head1 Legacy

The earliest development of C&lt;newgetopt.pl&gt; started in 1990, with Perl
version 4. As a result, its development, and the development of
Getopt::Long, has gone through several stages. Since backward
compatibility has always been extremely important, the current version
of Getopt::Long still supports a lot of constructs that nowadays are
no longer necessary or otherwise unwanted. This section describes
briefly some of these 'features'.

=head2 Default destinations

When no destination is specified for an option, GetOptions will store
the resultant value in a global variable named C&lt;opt_&gt;I&lt;XXX&gt;, where
I&lt;XXX&gt; is the primary name of this option. When a program executes
under C&lt;use strict&gt; (recommended), these variables must be
pre-declared with our() or C&lt;use vars&gt;.

    our $opt_length = 0;
    GetOptions ('length=i');	# will store in $opt_length

To yield a usable Perl variable, characters that are not part of the
syntax for variables are translated to underscores. For example,
C&lt;--fpp-struct-return&gt; will set the variable
C&lt;$opt_fpp_struct_return&gt;. Note that this variable resides in the
namespace of the calling program, not necessarily C&lt;main&gt;. For
example:

    GetOptions ("size=i", "sizes=i@");

with command line "-size 10 -sizes 24 -sizes 48" will perform the
equivalent of the assignments

    $opt_size = 10;
    @opt_sizes = (24, 48);

=head2 Alternative option starters

A string of alternative option starter characters may be passed as the
first argument (or the first argument after a leading hash reference
argument).

    my $len = 0;
    GetOptions ('/', 'length=i' =&gt; $len);

Now the command line may look like:

    /length 24 -- arg

Note that to terminate options processing still requires a double dash
C&lt;--&gt;.

GetOptions() will not interpret a leading C&lt;&lt; "&lt;&gt;" &gt;&gt; as option starters
if the next argument is a reference. To force C&lt;&lt; "&lt;" &gt;&gt; and C&lt;&lt; "&gt;" &gt;&gt; as
option starters, use C&lt;&lt; "&gt;&lt;" &gt;&gt;. Confusing? Well, B&lt;using a starter
argument is strongly deprecated&gt; anyway.

=head2 Configuration variables

Previous versions of Getopt::Long used variables for the purpose of
configuring. Although manipulating these variables still work, it is
strongly encouraged to use the C&lt;Configure&gt; routine that was introduced
in version 2.17. Besides, it is much easier.

=head1 Tips and Techniques

=head2 Pushing multiple values in a hash option

Sometimes you want to combine the best of hashes and arrays. For
example, the command line:

  --list add=first --list add=second --list add=third

where each successive 'list add' option will push the value of add
into array ref $list-&gt;{'add'}. The result would be like

  $list-&gt;{add} = [qw(first second third)];

This can be accomplished with a destination routine:

  GetOptions('list=s%' =&gt;
               sub { push(@{$list{$_[1]}}, $_[2]) });

=head1 Troubleshooting

=head2 GetOptions does not return a false result when an option is not supplied

That's why they're called 'options'.

=head2 GetOptions does not split the command line correctly

The command line is not split by GetOptions, but by the command line
interpreter (CLI). On Unix, this is the shell. On Windows, it is
COMMAND.COM or CMD.EXE. Other operating systems have other CLIs.

It is important to know that these CLIs may behave different when the
command line contains special characters, in particular quotes or
backslashes. For example, with Unix shells you can use single quotes
(C&lt;'&gt;) and double quotes (C&lt;"&gt;) to group words together. The following
alternatives are equivalent on Unix:

    "two words"
    'two words'
    two\ words

In case of doubt, insert the following statement in front of your Perl
program:

    print STDERR (join("|",@ARGV),"\n");

to verify how your CLI passes the arguments to the program.

=head2 Undefined subroutine &amp;main::GetOptions called

Are you running Windows, and did you write

    use GetOpt::Long;

(note the capital 'O')?

=head2 How do I put a "-?" option into a Getopt::Long?

You can only obtain this using an alias, and Getopt::Long of at least
version 2.13.

    use Getopt::Long;
    GetOptions ("help|?");    # -help and -? will both set $opt_help

Other characters that can't appear in Perl identifiers are also supported
as aliases with Getopt::Long of at least version 2.39.

As of version 2.32 Getopt::Long provides auto-help, a quick and easy way
to add the options --help and -? to your program, and handle them.

See C&lt;auto_help&gt; in section L&lt;Configuring Getopt::Long&gt;.

=head1 AUTHOR

Johan Vromans &lt;jvromans@squirrel.nl&gt;

=head1 COPYRIGHT AND DISCLAIMER

This program is Copyright 1990,2015 by Johan Vromans.
This program is free software; you can redistribute it and/or
modify it under the terms of the Perl Artistic License or the
GNU General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any
later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

If you do not have a copy of the GNU General Public License write to
the Free Software Foundation, Inc., 675 Mass Ave, Cambridge,
MA 02139, USA.

=cut

</pre></body></html>