<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Copyright Â© 2008-2011 RaphaĂ«l Hertzog &lt;hertzog@debian.org&gt;
# Copyright Â© 2008-2018 Guillem Jover &lt;guillem@debian.org&gt;
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

package Dpkg::Source::Format;

=encoding utf8

=head1 NAME

Dpkg::Source::Format - manipulate debian/source/format files

=head1 DESCRIPTION

This module provides an object that can manipulate Debian source
package F&lt;debian/source/format&gt; files.

=cut

use strict;
use warnings;

our $VERSION = '1.00';

use Dpkg::Gettext;
use Dpkg::ErrorHandling;

use parent qw(Dpkg::Interface::Storable);

=head1 METHODS

=over 4

=item $f = Dpkg::Source::Format-&gt;new(%opts)

Creates a new object corresponding to a source package's
F&lt;debian/source/format&gt; file. When the key B&lt;filename&gt; is set, it will
be used to parse and set the format. Otherwise if the B&lt;format&gt; key is
set it will be validated and used to set the format.

=cut

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;
    my $self = {
        filename =&gt; undef,
        major =&gt; undef,
        minor =&gt; undef,
        variant =&gt; undef,
    };
    bless $self, $class;

    if (exists $opts{filename}) {
        $self-&gt;load($opts{filename}, compression =&gt; 0);
    } elsif ($opts{format}) {
        $self-&gt;set($opts{format});
    }
    return $self;
}

=item $f-&gt;set_from_parts($major[, $minor[, $variant]])

Sets the source format from its parts. The $major part is mandatory.
The $minor and $variant parts are optional.

B&lt;Notice&gt;: This function performs no validation.

=cut

sub set_from_parts {
    my ($self, $major, $minor, $variant) = @_;

    $self-&gt;{major} = $major;
    $self-&gt;{minor} = $minor // 0;
    $self-&gt;{variant} = $variant;
}

=item ($major, $minor, $variant) = $f-&gt;set($format)

Sets (and validates) the source $format specified. Will return the parsed
format parts as a list, the optional $minor and $variant parts might be
undef.

=cut

sub set {
    my ($self, $format) = @_;

    if ($format =~ /^(\d+)(?:\.(\d+))?(?:\s+\(([a-z0-9]+)\))?$/) {
        my ($major, $minor, $variant) = ($1, $2, $3);

        $self-&gt;set_from_parts($major, $minor, $variant);

        return ($major, $minor, $variant);
    } else {
        error(g_("source package format '%s' is invalid"), $format);
    }
}

=item ($major, $minor, $variant) = $f-&gt;get()

=item $format = $f-&gt;get()

Gets the source format, either as properly formatted scalar, or as a list
of its parts, where the optional $minor and $variant parts might be undef.

=cut

sub get {
    my $self = shift;

    if (wantarray) {
        return ($self-&gt;{major}, $self-&gt;{minor}, $self-&gt;{variant});
    } else {
        my $format = "$self-&gt;{major}.$self-&gt;{minor}";
        $format .= " ($self-&gt;{variant})" if defined $self-&gt;{variant};

        return $format;
    }
}

=item $count = $f-&gt;parse($fh, $desc)

Parse the source format string from $fh, with filehandle description $desc.

=cut

sub parse {
    my ($self, $fh, $desc) = @_;

    my $format = &lt;$fh&gt;;
    chomp $format if defined $format;
    error(g_('%s is empty'), $desc)
        unless defined $format and length $format;

    $self-&gt;set($format);

    return 1;
}

=item $count = $f-&gt;load($filename)

Parse $filename contents for a source package format string.

=item $str = $f-&gt;output([$fh])

=item "$f"

Returns a string representing the source package format version.
If $fh is set, it prints the string to the filehandle.

=cut

sub output {
    my ($self, $fh) = @_;

    my $str = $self-&gt;get();

    print { $fh } "$str\n" if defined $fh;

    return $str;
}

=item $f-&gt;save($filename)

Save the source package format into the given $filename.

=back

=head1 CHANGES

=head2 Version 1.00 (dpkg 1.19.3)

Mark the module as public.

=cut

1;
</pre></body></html>